25 Years of Programming
An open source source for C, C++, OWL, BASIC, MDB, XLS, DOT, and more...

Home Projects Up Sitemap Search Blog Forum+Chat About Us Privacy Terms of Use Feedback FAQ Images Services Payments Humor Music

Language translation
by Google is available
when JavaScript enabled.
Google Translate
is an alternative.

GWBASIC program draws logistic map bifurcation diagram, graphic display of equation instability, deterministic chaos

The BIFURCAT.BAS program for GWBASIC or BASICA provides a graphical view of the logistic map bifurcation diagram, demonstrating equation instability and deterministic chaos, described briefly in the introduction to PARABOLA.BAS.

Other better versions:

H-100 DeSmet C. The page has links to the Borland OWL and Microsoft Visual C++ versions, and to the logistic map bifurcation diagram image gallery.

10 'BIFURCAT.BAS 3-11-90 
11 'COPYRIGHT (C)1990 STEVEN WHITNEY.
12 'Published under GNU GPL (General Public License) Version 3, with ABSOLUTELY NO WARRANTY.
13 'Initially published by http://25yearsofprogramming.com.
20 'SHOWS ROBERT MAY'S BIFURCATION DIAGRAM, AS DESCRIBED IN THE BOOK
30 'CHAOS: MAKING A NEW SCIENCE, BY JAMES GLEICK, PAGE 71.
40 '4-1-90  ADDED USER INPUT SECTION
50 'THE INTERESTING THINGS HAPPEN FROM 3.2 TO 4
60 'WINDOW SHOULD BE ADJUSTED TO GIVE MAXIMUM RESOLUTION FOR RANGE SHOWN
70 'SCREEN 12 : 'ENABLE FOR IBM BASIC
80 DEFDBL X
90 INPUT "LOWER BOUND (0 TO < 4)"; LOWER
100 INPUT "UPPER BOUND (= OR < 4)"; UPPER
110 STP = (UPPER - LOWER) / 160
120 PRINT "STEP INTERVAL WILL BE "; STP
130 PRINT : PRINT "PRESS ANY KEY...": PAUSE$ = INPUT$(1)
140 CLS
150 COLOUR = 2
160 WINDOW (LOWER, 0)-(UPPER, 1)
170 VIEW PRINT 24 TO 25
180 X = .02
190 FOR R = LOWER TO UPPER STEP STP
200	IF COLOUR = 2 THEN COLOUR = 4 ELSE IF COLOUR = 4 THEN COLOUR = 2
210	COLOR COLOUR
220	PRINT R;
230	FOR I = 1 TO 100:   ' ALLOW EQUATION TO SETTLE DOWN
240		X = R * X * (1 - X)
250	NEXT I
260	FOR I = 1 TO 1000
270		X = R * X * (1 - X)
280		PSET (R, X), COLOUR
290	NEXT I
300 NEXT R
310 BEEP: BEEP
320 VIEW PRINT
330 END